Player-Plates/build.gradle at master · nanite/Player-Plates · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
//file:noinspection GroovyAssignabilityCheck

plugins {
    id 'java-library'
    id 'fabric-loom' version '1.15-SNAPSHOT' apply(false)
    id 'net.neoforged.moddev' version '2.0.141' apply(false)
    id "me.modmuss50.mod-publish-plugin" version "1.1.0"
    id 'pro.mikey.plugins.insaniam' version "0.1-SNAPSHOT"
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    version = mod_version
    group = maven_group

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        options.release = 25
    }

    repositories {
        mavenLocal()
        maven {
            url = "https://maven.nanite.dev/releases"
        }
    }

    idea {
        module {
            downloadSources = true
            downloadJavadoc = true
        }
    }
}

subprojects {
    base {
        archivesName = "${archives_base_name}-$project.name"
    }

    if (project.name != "common") {
        dependencies {
            api project(":common")
        }

        jar {
            from project(":common").sourceSets.main.output
        }
    }

    def replaceProperties = [
            mod_id: mod_id,
            minecraft_version: minecraft_version,
            neoforge_version: neoforge_version,
            fabric_loader_version: fabric_loader_version,
            fabric_api_version: fabric_api_version,
            version: version,
    ]

    processResources {
        inputs.properties replaceProperties

        filesMatching(["META-INF/neoforge.mods.toml", "fabric.mod.json", "pack.mcmeta"]) {
            expand replaceProperties
        }
    }

    publishing {
        publications {
            register("maven${project.name.capitalize()}", MavenPublication) {
                artifactId = "${rootProject.archives_base_name}-${project.name}"
                from components.java
            }
        }

        repositories {
            def token = providers.environmentVariable("NANITE_TOKEN");
            if (token.isPresent()) {
                maven {
                    url "https://maven.nanite.dev/releases"
                    credentials {
                        username = "nanite"
                        password = providers.environmentVariable("NANITE_TOKEN").get()
                    }
                }
            }
        }
    }
}

def changelogData = insaniamUtils.createChangelog {
    file = file('CHANGELOG.md')
    versionPattern = ~/## \[[^]]+]/
    fallbackValue = "No changelog provided"
    version = project.mod_version
}

publishMods {
    dryRun = providers.environmentVariable("CURSE_TOKEN").getOrNull() == null
    changelog = changelogData
    version = "${mod_version}"
    type = STABLE
    def compatibleMcVersions = extra_compatible_minecraft_versions.split(',')

    def fabricOptions = publishOptions {
        file = project.provider { project(":fabric").tasks.jar }.flatMap { it.archiveFile }
        displayName = "${project.name} Fabric ${mod_version}+mc${minecraft_version}"
        modLoaders.add("fabric")
    }

    def neoOptions = publishOptions {
        file = project.provider { project(":neoforge").tasks.jar }.flatMap { it.archiveFile }
        displayName = "${project.name} NeoForged ${mod_version}+mc${minecraft_version}"
        modLoaders.add("neoforge")
    }

    def curseForgeOptions = curseforgeOptions {
        accessToken = providers.environmentVariable("CURSE_TOKEN")
        projectId = "${curseforge_id}"
        minecraftVersions.add("${minecraft_version}")
        compatibleMcVersions.each { mcVer ->
            minecraftVersions.add(mcVer.trim())
        }
    }

    def modrinthOptions = modrinthOptions {
        accessToken = providers.environmentVariable("MODRINTH_TOKEN")
        projectId = "${modrinth_id}"
        minecraftVersions.add("${minecraft_version}")
        compatibleMcVersions.each { mcVer ->
            minecraftVersions.add(mcVer.trim())
        }
    }

    curseforge("curseforgeFabric") {
        from(curseForgeOptions, fabricOptions)
        requires("fabric-api")
        requires("nanite-library")
    }

    curseforge("curseforgeNeo") {
        from(curseForgeOptions, neoOptions)
        requires("nanite-library")
    }

    if (providers.environmentVariable("MODRINTH_TOKEN").getOrNull() != null) {
        modrinth("modrinthFabric") {
            from(modrinthOptions, fabricOptions)
            requires("fabric-api")
//            requires("nanite-library")
        }

        modrinth("modrinthNeo") {
            from(modrinthOptions, neoOptions)
//            requires("nanite-library")
        }
    }

    github {
        file = project.provider { project(":neoforge").tasks.jar }.flatMap { it.archiveFile }
        additionalFiles.from project.provider { project(":fabric").tasks.jar }.flatMap { it.archiveFile }
        repository = "${github_repo}"
        accessToken = providers.environmentVariable("GITHUB_TOKEN")
        commitish = providers.environmentVariable("GITHUB_SHA").orElse("dryRun")
        tagName = providers.environmentVariable("GITHUB_REF_NAME").orElse("dryRun")
    }
}