flake.nix

{
  description = "Project dev environment as Nix shell + DockerTools layered image";

  inputs = {
    nixpkgs.url      = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url  = "github:numtide/flake-utils";
    lib.url          = "github:jeff-hykin/quick-nix-toolkits";
    lib.inputs.flakeUtils.follows = "flake-utils";
    xome.url         = "github:jeff-hykin/xome";
    xome.inputs.nixpkgs.follows    = "nixpkgs";
    xome.inputs.flake-utils.follows = "flake-utils";
    diagon.url       = "github:petertrotman/nixpkgs/Diagon";
    # nixpkgs' lcm does not build on darwin, and the C++ native module flakes
    # already take it from here.
    lcm-extended.url = "github:jeff-hykin/lcm_extended";
    lcm-extended.inputs.nixpkgs.follows = "nixpkgs";
    lcm-extended.inputs.flake-utils.follows = "flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils, lib, xome, diagon, lcm-extended, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };

        # ------------------------------------------------------------
        # 1. Shared package list (tool-chain + project deps)
        # ------------------------------------------------------------
        # we "flag" each package with what we need it for (e.g. LD_LIBRARY_PATH, nativeBuildInputs vs buildInputs, etc)
        aggregation = lib.aggregator [
          ### Core shell & utils
          { vals.pkg=pkgs.bashInteractive;    flags={}; }
          { vals.pkg=pkgs.coreutils;          flags={}; }
          { vals.pkg=pkgs.gh;                 flags={}; }
          { vals.pkg=pkgs.stdenv.cc.cc.lib;   flags.ldLibraryGroup=true; }
          { vals.pkg=pkgs.stdenv.cc;          flags.ldLibraryGroup=true; }
          { vals.pkg=pkgs.gfortran.cc.lib;    flags.ldLibraryGroup=true; }
          { vals.pkg=pkgs.cctools;            flags={}; onlyIf=pkgs.stdenv.isDarwin; } # for pip install opencv-python
          { vals.pkg=pkgs.pcre2;              flags={ ldLibraryGroup=pkgs.stdenv.isDarwin; packageConfGroup=pkgs.stdenv.isDarwin; }; }
          { vals.pkg=pkgs.libsysprof-capture; flags.packageConfGroup=true; onlyIf=pkgs.stdenv.isDarwin; }
          { vals.pkg=pkgs.xcbuild;            flags={}; onlyIf=pkgs.stdenv.isDarwin; }
          { vals.pkg=pkgs.git-lfs;            flags={}; }
          { vals.pkg=pkgs.gnugrep;            flags={}; }
          { vals.pkg=pkgs.gnused;             flags={}; }
          { vals.pkg=pkgs.iproute2;           flags={}; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.pkg-config;         flags={}; }
          { vals.pkg=pkgs.git;                flags={}; }
          { vals.pkg=pkgs.opensshWithKerberos;flags={}; }
          { vals.pkg=pkgs.unixtools.ifconfig; flags={}; }
          { vals.pkg=pkgs.unixtools.netstat;  flags={}; }

          # when pip packages call cc with -I/usr/include, that causes problems on some machines, this swaps that out for the nix cc headers
          # this is only necessary for pip packages from venv, pip packages from nixpkgs.python312Packages.* already have "-I/usr/include" patched with the nix equivalent
          {
            vals.pkg=(pkgs.writeShellScriptBin
              "cc-no-usr-include"
              ''
                #!${pkgs.bash}/bin/bash
                set -euo pipefail

                real_cc="${pkgs.stdenv.cc}/bin/gcc"

                args=()
                for a in "$@"; do
                case "$a" in
                    -I/usr/include|-I/usr/local/include)
                    # drop these
                    ;;
                    *)
                    args+=("$a")
                    ;;
                esac
                done

                exec "$real_cc" "''${args[@]}"
              ''
            );
            flags={};
          }

          ### Python + static analysis
          { vals.pkg=pkgs.python312;                    flags={}; vals.pythonMinorVersion="12";}
          { vals.pkg=pkgs.python312Packages.pip;        flags={}; }
          { vals.pkg=pkgs.python312Packages.setuptools; flags={}; }
          { vals.pkg=pkgs.python312Packages.virtualenv; flags={}; }
          { vals.pkg=pkgs.uv;                             flags={}; }
          { vals.pkg=pkgs.pre-commit;                   flags={}; }

          ### Runtime deps
          { vals.pkg=pkgs.portaudio;                 flags={ldLibraryGroup=true; packageConfGroup=true;}; }
          { vals.pkg=pkgs.ffmpeg_6;                  flags={}; }
          { vals.pkg=pkgs.ffmpeg_6.dev;              flags={}; }

          ### Graphics / X11 stack
          { vals.pkg=pkgs.libGL;              flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libGLU;             flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.mesa;               flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.glfw;               flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libx11;             flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxi;              flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxext;            flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxrandr;          flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxinerama;        flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxcursor;         flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxfixes;          flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxrender;         flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxdamage;         flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxcomposite;      flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxcb;             flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxscrnsaver;      flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.libxxf86vm;         flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.udev;               flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.SDL2;               flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.SDL2.dev;           flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.zlib;               flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }

          ### GTK / OpenCV helpers
          { vals.pkg=pkgs.glib;                  flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.gtk3;                  flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.gdk-pixbuf;            flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.gobject-introspection; flags.ldLibraryGroup=true; onlyIf=pkgs.stdenv.isLinux; }

          ### GStreamer
          { vals.pkg=pkgs.gst_all_1.gstreamer;          flags.ldLibraryGroup=true; flags.giTypelibGroup=true; }
          { vals.pkg=pkgs.gst_all_1.gst-plugins-base;   flags.ldLibraryGroup=true; flags.giTypelibGroup=true; }
          { vals.pkg=pkgs.gst_all_1.gst-plugins-good;   flags={}; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.gst_all_1.gst-plugins-bad;    flags={}; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.gst_all_1.gst-plugins-ugly;   flags={}; onlyIf=pkgs.stdenv.isLinux; }
          { vals.pkg=pkgs.python312Packages.gst-python; flags={}; onlyIf=pkgs.stdenv.isLinux; }

          ### Open3D & build-time
          { vals.pkg=pkgs.eigen;         flags={}; }
          { vals.pkg=pkgs.cmake;         flags={}; }
          { vals.pkg=pkgs.ninja;         flags={}; }
          { vals.pkg=pkgs.jsoncpp;       flags={}; }
          { vals.pkg=pkgs.libjpeg;       flags.ldLibraryGroup=true; }
          { vals.pkg=pkgs.libjpeg_turbo; flags.ldLibraryGroup=true; }
          { vals.pkg=pkgs.libpng;        flags={}; }
          { vals.pkg=pkgs.libidn2;       flags.ldLibraryGroup=true; }

          ### Docs generators
          { vals.pkg=pkgs.pikchr;        flags={}; }
          { vals.pkg=pkgs.graphviz;      flags={}; }
          { vals.pkg=pkgs.imagemagick;   flags={}; }
          { vals.pkg=diagon.legacyPackages.${system}.diagon;   flags={}; }

          ### LCM (Lightweight Communications and Marshalling)
          # Only darwin took lcm's own python bindings before, and linux still
          # gets them from the venv.
          {
            vals.pkg=lcm-extended.packages.${system}.lcm;
            flags={ ldLibraryGroup=true; manualPythonPackages=pkgs.stdenv.isDarwin; };
          }
          { vals.pkg=pkgs.cyclonedds; flags.ldLibraryGroup=true; flags.packageConfGroup=true; }
        ];

        # ------------------------------------------------------------
        # 2. group / aggregate our packages
        # ------------------------------------------------------------
        devPackages = aggregation.getAll { attrPath=[ "pkg" ]; };
        ldLibraryPackages = aggregation.getAll { hasAllFlags=[ "ldLibraryGroup" ]; attrPath=[ "pkg" ]; };
        giTypelibPackagesString = aggregation.getAll {
          hasAllFlags=[ "giTypelibGroup" ];
          attrPath=[ "pkg" ];
          strAppend="/lib/girepository-1.0";
          strJoin=":";
        };
        packageConfPackagesString = (aggregation.getAll {
            hasAllFlags=[ "packageConfGroup" ];
            attrPath=[ "pkg" ];
            strAppend="/lib/pkgconfig";
            strJoin=":";
        });
        manualPythonPackages = (aggregation.getAll {
            hasAllFlags=[ "manualPythonPackages" ];
            attrPath=[ "pkg" ];
            strAppend="/lib/python3.${aggregation.mergedVals.pythonMinorVersion}/site-packages";
            strJoin=":";
        });

        # ------------------------------------------------------------
        # 3. Host interactive shell  →  `nix develop`
        # ------------------------------------------------------------
        shellHook = ''
          shopt -s nullglob 2>/dev/null || setopt +o nomatch 2>/dev/null || true # allow globs to be empty without throwing an error
          if [ "$OSTYPE" = "linux-gnu" ]; then
            export CC="cc-no-usr-include" # basically patching for nix
            # Create nvidia-only lib symlinks to avoid glibc conflicts
            NVIDIA_LIBS_DIR="/tmp/nix-nvidia-libs"
            mkdir -p "$NVIDIA_LIBS_DIR"
            for lib in /usr/lib/libcuda.so* /usr/lib/libnvidia*.so* /usr/lib/x86_64-linux-gnu/libnvidia*.so*; do
              [ -e "$lib" ] && ln -sf "$lib" "$NVIDIA_LIBS_DIR/" 2>/dev/null
            done
          fi
          export LD_LIBRARY_PATH="$NVIDIA_LIBS_DIR:${pkgs.lib.makeLibraryPath ldLibraryPackages}:$LD_LIBRARY_PATH"
          export LIBRARY_PATH="$LD_LIBRARY_PATH" # fixes python find_library for pyaudio
          export DISPLAY=:0
          export GI_TYPELIB_PATH="${giTypelibPackagesString}:$GI_TYPELIB_PATH"
          export PKG_CONFIG_PATH=${lib.escapeShellArg packageConfPackagesString}
          export PYTHONPATH="$PYTHONPATH:"${lib.escapeShellArg manualPythonPackages}
          # Strip 3.13 site-packages leaked by setup hooks of py-built tools
          # (pre-commit etc). They shadow the uv-managed 3.12's _sysconfigdata,
          # making sysconfig report SOABI=cpython-313, which trips setuptools
          # wheel-tag validation.
          export PYTHONPATH="$(printf '%s' "$PYTHONPATH" | tr ':' '\n' | grep -v '/python3\.13/' | paste -sd:)"
          export CYCLONEDDS_HOME="${pkgs.cyclonedds}"
          export CMAKE_PREFIX_PATH="${pkgs.cyclonedds}:$CMAKE_PREFIX_PATH"
          # CC, CFLAGS, and LDFLAGS are bascially all for `pip install pyaudio`
          export CFLAGS="$(pkg-config --cflags portaudio-2.0) $CFLAGS"
          export LDFLAGS="-L$(pkg-config --variable=libdir portaudio-2.0) $LDFLAGS"

          # without this alias, the pytest uses the non-venv python and fails
          alias pytest="python -m pytest"

          PROJECT_ROOT=$(git rev-parse --show-toplevel 2>/dev/null || echo "$PWD")
          if [ -f "$PROJECT_ROOT/env/bin/activate" ]; then
            . "$PROJECT_ROOT/env/bin/activate"
          fi

          [ -f "$PROJECT_ROOT/motd" ] && cat "$PROJECT_ROOT/motd"
          # Resolve the real hooks dir (shared across worktrees, where .git is a
          # file pointing elsewhere) so we don't re-run `pre-commit install` and
          # trip its "refusing with core.hooksPath set" error.
          HOOKS_DIR=$(git -C "$PROJECT_ROOT" rev-parse --git-path hooks 2>/dev/null)
          [ -f "$PROJECT_ROOT/.pre-commit-config.yaml" ] && [ -n "$HOOKS_DIR" ] && [ ! -f "$HOOKS_DIR/pre-commit" ] && pre-commit install --install-hooks
        '';
        devShells = {
          # basic shell (blends with your current environment)
          default = pkgs.mkShell {
            buildInputs = devPackages;
            shellHook = shellHook;
          };
          # strict shell (creates a fake home, only select exteral commands (e.g. sudo) from your system are available)
          isolated = (xome.simpleMakeHomeFor {
            inherit pkgs;
            pure = true;
            commandPassthrough = [ "sudo" "nvim" "code" "sysctl" "sw_vers" "git" "vim" "emacs" "openssl" "ssh" "osascript" "otool" "hidutil" "logger" "codesign" ]; # e.g. use external nvim instead of nix's
            # commonly needed for MacOS: [ "osascript" "otool" "hidutil" "logger" "codesign" ]
            homeSubpathPassthrough = [ "cache/nix/" ]; # share nix cache between projects
            homeModule = {
              # for home-manager examples, see:
              # https://deepwiki.com/nix-community/home-manager/5-configuration-examples
              # all home-manager options:
              # https://nix-community.github.io/home-manager/options.xhtml
              home.homeDirectory = "/tmp/virtual_homes/dimos";
              home.stateVersion = "25.11";
              home.packages = devPackages;

              programs = {
                home-manager = {
                  enable = true;
                };
                zsh = {
                  enable = true;
                  enableCompletion = true;
                  autosuggestion.enable = true;
                  syntaxHighlighting.enable = true;
                  shellAliases.ll = "ls -la";
                  history.size = 100000;
                  # this is kinda like .zshrc
                  initContent = ''
                    # most people expect comments in their shell to to work
                    setopt interactivecomments
                    # fix emoji prompt offset issues (this shouldn't lock people into English b/c LANG can be non-english)
                    export LC_CTYPE=en_US.UTF-8
                    ${shellHook}
                  '';
                };
                starship = {
                  enable = true;
                  enableZshIntegration = true;
                  settings = {
                    character = {
                      success_symbol = "[▣](bold green)";
                      error_symbol = "[▣](bold red)";
                    };
                  };
                };
              };
            };
          }).default;
        };

        # ------------------------------------------------------------
        # 4. Closure copied into the OCI image rootfs
        # ------------------------------------------------------------
        imageRoot = pkgs.buildEnv {
          name = "dimos-image-root";
          paths = devPackages;
          pathsToLink = [ "/bin" ];
        };

      in {
        ## Local dev shell
        devShells = devShells;

        ## Layered docker image with DockerTools
        packages.devcontainer = pkgs.dockerTools.buildLayeredImage {
          name      = "dimensional/dimos-dev";
          tag       = "latest";
          contents  = [ imageRoot ];
          config = {
            WorkingDir = "/workspace";
            Cmd        = [ "bash" ];
          };
        };
      });
}