FTB-Essentials/build.gradle at main · FTBTeam/FTB-Essentials · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
plugins {
    id 'java-library'
    id 'net.fabricmc.fabric-loom' version '1.15.2' apply(false)
    id 'net.neoforged.moddev' version '2.0.141' apply(false)
    id "me.modmuss50.mod-publish-plugin" version "1.1.0"
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}

base {
    archivesName = archives_base_name
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    apply from: 'https://raw.githubusercontent.com/FTBTeam/mods-meta/v1/gradle/maven.gradle'
    apply from: 'https://raw.githubusercontent.com/FTBTeam/mods-meta/v1/gradle/publishing-2.gradle'
    apply from: 'https://raw.githubusercontent.com/FTBTeam/mods-meta/v1/gradle/utils.gradle'
    apply from: 'https://raw.githubusercontent.com/FTBTeam/mods-meta/v1/gradle/changelog.gradle'

    version = createModVersion(project)
    group = project.maven_group

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        options.release = 25
    }

    dependencies {
//        testImplementation 'org.junit.jupiter:junit-jupiter:5.11.0-M1'
    }

    java {
        withSourcesJar()
    }
}

subprojects {
    base {
        archivesName = rootProject.base.archivesName.get() + (project.name != "common" ? "-" + project.name : "")
    }

    if (project.name != "common") {
        dependencies {
            api project(":common")
        }

        jar {
            from project(":common").sourceSets.main.output
        }
    }

    repositories {
        mavenCentral()
        commonMavenRepos(repositories)
    }

    processResources {
        exclude '.cache'

        inputs.property "version", project.version

        filesMatching(["META-INF/neoforge.mods.toml", "fabric.mod.json"]) {
            expand "version": project.version,
                    "neoforge_version_range": neoforge_version_range,
                    "neoforge_loader_version": neoforge_loader_version,
                    "minecraft_version_range_maven": minecraft_version_range_maven,
                    "minecraft_version_range_semver": minecraft_version_range_semver,
                    "fabricapi_version_range": fabric_api_version_range,
                    "ftb_library_version_range_semver": ftb_library_version_range_semver,
                    "ftb_library_version_range_maven": ftb_library_version_range_maven,
                    "ftb_ranks_version_range_semver": ftb_ranks_version_range_semver,
                    "ftb_ranks_version_range_maven": ftb_ranks_version_range_maven
        }
    }

    createMavenPublishingBlock(project)
}

idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}

publishMods {
    dryRun = providers.environmentVariable("CURSEFORGE_KEY").getOrNull() == null || providers.environmentVariable("SKIP_CURSEFORGE").getOrNull() != null
    changelog = createChangelog(project)
    version = project.version
    type = createReleaseType(project)

    def createOptions = (String projectName) -> {
        publishOptions {
            file = project.provider { project(":$projectName").tasks.jar }.flatMap { it.archiveFile }
            displayName = "${readable_name} ${projectName.capitalize()} ${project.version}"
            modLoaders.add(projectName.toLowerCase())
        }
    }

    def fabricOptions = createOptions("fabric")
    def neoForgeOptions = createOptions("neoforge")

    def curseForgeOptions = curseforgeOptions {
        accessToken = providers.environmentVariable("CURSEFORGE_KEY")
        supported_minecraft_versions.split(",").each {
            minecraftVersions.add(it.trim())
        }
        javaVersions.add(JavaVersion.VERSION_25)
    }

    curseforge("curseforgeFabric") {
        from(curseForgeOptions, fabricOptions)
        projectId = curseforge_id
        requires('fabric-api')
        requires('ftb-library-fabric')
        optional('ftb-ranks-fabric')
    }

    curseforge("curseforgeNeoForge") {
        from(curseForgeOptions, neoForgeOptions)
        projectId = curseforge_id
        requires('ftb-library-forge')
        optional('ftb-ranks-forge')
    }
}