Add tests around adding games to a user's collection

Author: Chris Rees

lib/agoneum/account/account.ex

@@ -5,8 +5,7 @@ defmodule Agoneum.Account do
 
   import Ecto.Query, warn: false
   alias Agoneum.Repo
-
-  alias Agoneum.Account.User
+  alias Agoneum.{Account.User, Games.Game}
 
   @doc """
   Returns the list of users.
@@ -120,4 +119,18 @@ defmodule Agoneum.Account do
   def change_user(%User{} = user) do
     User.changeset(user, %{})
   end
+
+  @doc """
+  Adds a new game (or games) to the user's collection.
+  """
+  def add_games(%User{} = user, %Game{} = game), do: add_games(user, [game])
+  def add_games(%User{} = user, games) do
+    game_changesets = Enum.map(games ++ user.games, &Ecto.Changeset.change/1)
+                      |> Enum.uniq()
+
+    user
+    |> change_user()
+    |> Ecto.Changeset.put_assoc(:games, game_changesets)
+    |> Repo.update()
+  end
 end

lib/agoneum/games/game.ex

@@ -8,7 +8,6 @@ defmodule Agoneum.Games.Game do
   @optional_fields ~w(year image)a
   @all_fields @required_fields ++ @optional_fields
 
-  # TODO: Add a unique constraint for name/year combo
   schema "games" do
     field :description, :string
     field :image, :string

test/agoneum/account/account_test.exs

@@ -1,14 +1,13 @@
 defmodule Agoneum.AccountTest do
   use Agoneum.DataCase
 
-  alias Agoneum.Account
+  alias Agoneum.{Account, Account.User, Games}
 
   describe "users" do
-    alias Agoneum.Account.User
-
     @valid_attrs %{email: "email@agoneum.com", name: "some name", password: "some password"}
     @update_attrs %{email: "updated@agoneum.com", name: "some updated name", password: "some updated password"}
     @invalid_attrs %{email: nil, name: nil, password_hash: nil}
+    @game_attrs %{description: "Kill your friends", max_players: 7, min_players: 4, name: "BANG!", year: 2002}
 
     def user_fixture(attrs \\ %{}) do
       {:ok, user} =
@@ -17,6 +16,17 @@ defmodule Agoneum.AccountTest do
         |> Account.create_user()
 
       user
+      |> Agoneum.Repo.preload(:games)
+    end
+
+    def game_fixture(attrs \\ %{}) do
+      {:ok, game} =
+        attrs
+        |> Enum.into(@game_attrs)
+        |> Games.create_game()
+
+      game
+      |> Agoneum.Repo.preload(:users)
     end
 
     test "list_users/0 returns all users" do
@@ -102,5 +112,47 @@ defmodule Agoneum.AccountTest do
       user = user_fixture()
       assert %Ecto.Changeset{} = Account.change_user(user)
     end
+
+    test "add_games/2 associates a game with the user" do
+      user = user_fixture()
+      game = game_fixture()
+      assert length(user.games) == 0
+
+      assert {:ok, user} = Account.add_games(user, game)
+      assert length(user.games) == 1
+    end
+
+    test "add_games/2 adds new games to the user's list" do
+      user = user_fixture()
+      game = game_fixture()
+      game2 = game_fixture(%{name: "BANG! High Noon"})
+
+      {:ok, user} = Account.add_games(user, game)
+      {:ok, user} = Account.add_games(user, game2)
+
+      assert length(user.games) == 2
+    end
+
+    test "add_games/2 adds to a user's list of games without creating duplicates" do
+      user = user_fixture()
+      game = game_fixture()
+      game2 = game_fixture(%{name: "BANG! High Noon"})
+      assert length(user.games) == 0
+
+      {:ok, user} = Account.add_games(user, game)
+      {:ok, user} = Account.add_games(user, [game, game2])
+      assert length(user.games) == 2
+    end
+
+    test "add_games/2 associates a game with multiple users" do
+      user1 = user_fixture(%{email: "user1@agoneum.com", name: "User 1"})
+      user2 = user_fixture(%{email: "user2@agoneum.com", name: "User 2"})
+      game = game_fixture()
+
+      assert {:ok, user1} = Account.add_games(user1, game)
+      assert {:ok, user2} = Account.add_games(user2, game)
+
+      assert List.first(user1.games).id == List.first(user2.games).id
+    end
   end
 end