SOLIDITY/SimpleEscrow.sol at main · Dev-In-Crypt/SOLIDITY · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
// SPDX-License-Identifier: MIT

pragma solidity ^0.8.30;

contract SimpleEscrow {
    address public buyer;
    address public seller;
    address public arbiter;

    uint256 public amount;
    bool public funded;
    bool public released;
    bool public refunded;

    error ZeroAddress();
    error AmountZero();
    error NotBuyer();
    error NotSeller();
    error NotArbiter();
    error NotParticipant();
    error AlreadyFunded();
    error NotFunded();
    error AlreadyFinalized();

    event Funded(address indexed buyer, uint256 amount);
    event Released(address indexed seller, uint256 amount);
    event Refunded(address indexed buyer, uint256 amount);

    constructor(address _buyer, address _seller, address _arbiter) {
        if (_buyer == address(0) || _seller == address(0) || _arbiter == address(0)) revert ZeroAddress();
        buyer = _buyer;
        seller = _seller;
        arbiter = _arbiter;
    }

    function fund() external payable {
        if (msg.sender != buyer) revert NotBuyer();
        if (funded) revert AlreadyFunded();
        if (msg.value == 0) revert AmountZero();

        funded = true;
        amount = msg.value;

        emit Funded(buyer, msg.value);
    }

    function releaseToSeller() external {
        if (!funded) revert NotFunded();
        if (released || refunded) revert AlreadyFinalized();
        if (msg.sender != buyer && msg.sender != arbiter) revert NotParticipant();

        released = true;

        (bool ok, ) = seller.call{value: amount}("");
        require(ok);

        emit Released(seller, amount);
    }

    function refundToBuyer() external {
        if (!funded) revert NotFunded();
        if (released || refunded) revert AlreadyFinalized();
        if (msg.sender != seller && msg.sender != arbiter) revert NotParticipant();

        refunded = true;

        (bool ok, ) = buyer.call{value: amount}("");
        require(ok);

        emit Refunded(buyer, amount);
    }
}